***********************************************************************
***********           PANJIT International Co Ltd           ***********
***********************************************************************
*May 31, 2019                                                         *
*                                                                     *
*This SPICE Model describes the characteristics of a typical device   *
*and does not respresent the specification. Designer should refer to  *
*the same type name data sheet for specification limits.              *
***********************************************************************
*$
.subckt   PJS6415A-AU   D   G   S
*****param & model definition***
.model  dmos  pmos(
+    l = 1e-6		  w = 1e-6		level = 3
+  vto = -1.		 kp = 26.2)
.model  dds   d(
+   is = 1.694e-9	  n = 1.207		   rs = 8.083e-2
+   eg = 1.000	trs1 = 1.000e-3)
.model  dbody d(
+   is = 1.694e-9	  n = 1.207		   rs = 8.083e-2
+  cjo = 8.558e-11	  m = 3.436e-1		   vj = 1.639e-1
+   bv = 22 		ibv = 250e-6		 tbv1 = 3.999e-4		tt = 25n
;+ trs1 = -2.500e-3	ikf= 0.1)
.model  inter  pmos(
+  vto = 0		 kp = 10		level = 1)
.model  dgd    d(
+  cjo = 5.938e-10	  m = 5.673e-1		   vj = 2.776e-1)
.param
+  cgs = 1.495e-9	cgd = 5.918e-10
+   rd = 2.459e-2	 ra = 1.000e-3		trd = 3.533e-3
*****function & circuit***
rg	  G  1t   1
cgs	 1t   3   {cgs}
egv	  3  2t   table   {v(S, 1t)}
+((0   , 0   ),
+ (0.5 , 0),
+ (1   , 1   ),
+ (1.5 , 1.5 ),
;+ (1.8 , 1.8 ),
+ (2   , 2.1   ),
;+ (2.1   , 2.05   ),
;+ (2.2   , 2.1   ),
;+ (2.3   , 2.15   ),
;+ (2.4   , 2.18   ),
+ (2.5 , 2.5 ),
+ (3   , 2.8  ),
+ (4.5 , 3.6),
+ (5 , 3.7),
+ (12  , 5),
+ (14  , 5))
egt	  1  2t   value = {1.287e-3*limit(v(2t,3),-5,0)*limit((temp-25),-80,125)}
mmain	  2   1   3   3   dmos
rd	  D   4   {rd}    tc = {trd}
dds	  4   3   dds
dbody	  D   3   dbody
ra	  4   2   {ra}
rs	  3   5   1e-4
ls	  5   S   0.001n
m1       1t   8   6   6   inter
e1        8   6   4   1t  2
cgd	  7   4   {cgd}
rcgd      7   4   10meg
dgd       4   6   dgd
rdgd      4   6   10meg
m2        7   9  1t  1t   inter
e2        9  1t   4  1t   -2
.ends
*$
